on *:START: {
  RegisterLink
}

raw AUTHUSER:*: {
  ;## Guest login; change your password.
  ;/raw LOGIN guest abc234343D
  
  ;## Registered user login.
  /raw LOGINH <Your Username> $md5(<Your password>)
}

raw 001:*: {
  if (%rm) /create %rm
  unset %rm
  %servip = $serverip
}

;*************** ------------------------ ***************
;*************** web link processing code ***************
; credit: http://members.lycos.co.uk/onln/files/ProcessLink.txt
alias RegisterLink {
  echo -ac info *** Registering IRC URL Handler...
  var %x = rl $+ $ticks
  _regOpen   %x
  $_regWrite(%x, HKCR\irc\Shell\open\ddeexec\,        /ProcessLink % $+ 1)
  $_regWrite(%x, HKCR\irc\Shell\open\ddeexec\ifexec\, /ProcessLink % $+ 1)
  $_regWrite(%x, HKCR\irc\Shell\open\ddeexec\Topic\,  Command)
  _regClose  %x
  echo -ac info *** Done.
}

alias ProcessLink {
  echo -ac info *** Processing IRC URL: $1

  ; Insert your code here. URL is represented as $1
  ;
  ; The URL format is explained in this page:
  ;   http://www.mirc.com/mirclink.html

  ; Parse server name
  %serv = $gettok($1,1,$asc(?))
  %serv = $remove(%serv, irc:)
  %serv = $remove(%serv, /)
  
  ; Parse channel name
  %rm = $gettok($1,2,$asc(?))
  %rm = $remove(%rm, rm=)
  
  ; If connected to the same server then goto the channel;
  ; Else connect to server first and then goto the channel.
  if (%servip == $serverip) { 
    /create %rm
    unset %rm
  }
  else /server %serv 6667
}

; Registry manipulation aliases
;
; Methods are explained in the Windows Script Host documentation.
alias -l _regOpen  .comopen  $$1 WScript.Shell
alias -l _regClose .comclose $$1
alias -l _regWrite {
  !.echo -q $com($1, RegWrite, 1, bstr, $2, bstr, $$3, bstr, REG_SZ)
}
alias -l _regRead {
  !.echo -q $com($1, RegRead, 1, bstr, $$2)
  return $com($1).result
}
alias -l _regDel {
  !.echo -q $com($1, RegDelete, 1, bstr, $$2)
}
;*************** ------------------------ ***************
;*************** ------------------------ ***************